ObsOutputList.f90

Go to the documentation of this file.

!> @brief This module defines the derived type ObsOutputListType
!!
!! This module contains a list of ObsOutputType objects and
!! methods needed for coordinating between an ObsType object and its
!! ObsOutputType objects.  Like ObsOutputType, ObsOutputListType is
!! needed only for processing continuous observations.
!!
!<
module obsoutputlistmodule
 
  use kindmodule, only: dp, i4b
  use inputoutputmodule, only: same_word
  use listmodule, only: listtype
  use obsoutputmodule, only: obsoutputtype, constructobsoutput, &
                             addobsoutputtolist, getobsoutputfromlist
 
  implicit none
 
  private
  public :: obsoutputlisttype
 
  type obsoutputlisttype
    ! -- Private members
    type(listtype), private :: obsoutputs
  contains
    ! -- Public procedures
    procedure, public :: add
    procedure, public :: resetallobsemptylines
    procedure, public :: containsfile
    procedure, public :: count
    procedure, public :: get
    procedure, public :: writeallobslinereturns
    procedure, public :: clear
    procedure, public :: deallocobsoutputlist
  end type obsoutputlisttype
 
contains
 
  !> @ brief Reset empty line logical for all observations
  !!
  !!  Subroutine to reset the empty line logical for all ObsOutputType
  !!  objects in the list.
  !!
  !<
  subroutine resetallobsemptylines(this)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    ! -- local
    integer(I4B) :: i, num
    type(obsoutputtype), pointer :: obsOutput => null()
    !
    num = this%Count()
    do i = 1, num
      obsoutput => this%Get(i)
      call obsoutput%ResetObsEmptyLine()
    end do
    !
    ! -- return
    return
  end subroutine resetallobsemptylines
 
  !> @ brief Count the number of ObsOutputType objects
  !!
  !!  Subroutine to return the number of ObsOutputType objects in the list.
  !!
  !<
  function count(this)
    ! -- return
    integer(I4B) :: count !< number of ObsOutputType objects
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    !
    count = this%ObsOutputs%Count()
    !
    ! -- return
    return
  end function count
 
  !> @ brief Determine if a file name is in the list of ObsOutputType objects
  !!
  !!  Function to determine if a file name is in the list of
  !!  ObsOutptType objects.
  !!
  !<
  logical function containsfile(this, fname)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    character(len=*), intent(in) :: fname !< observation output file name
    ! -- local
    type(obsoutputtype), pointer :: obsoutput => null()
    integer(I4B) :: i, n
    !
    containsfile = .false.
    n = this%Count()
    loop1: do i = 1, n
      obsoutput => this%Get(i)
      if (same_word(obsoutput%filename, fname)) then
        containsfile = .true.
        exit loop1
      end if
    end do loop1
    !
    ! -- return
    return
  end function containsfile
 
  !> @ brief Add a ObsOutputType object to the list
  !!
  !!  Subroutine to add a new ObsOutputType object to the ObsOutputList and
  !!  assign ObsOutputType members.
  !!
  !<
  subroutine add(this, fname, nunit)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    character(len=*), intent(in) :: fname !< observation output file name
    integer(I4B), intent(in) :: nunit !< observation output unit number
    ! -- local
    type(obsoutputtype), pointer :: obsOutput => null()
    !
    call constructobsoutput(obsoutput, fname, nunit)
    call addobsoutputtolist(this%ObsOutputs, obsoutput)
    !
    ! -- return
    return
  end subroutine add
 
  !> @ brief Write line returns for all ObsOutputListType
  !!
  !!  Subroutine to write line returns for a time step for all observation
  !!  output files in a ObsOutputListType.
  !!
  !<
  subroutine writeallobslinereturns(this)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    ! -- local
    type(obsoutputtype), pointer :: obsOutput => null()
    integer(I4B) :: i, num
    !
    num = this%Count()
    do i = 1, num
      obsoutput => this%Get(i)
      if (obsoutput%FormattedOutput) then
        call obsoutput%WriteObsLineReturn()
      end if
    end do
    !
    ! -- return
    return
  end subroutine writeallobslinereturns
 
  !> @ brief Get an item from a ObsOutputListType
  !!
  !!  Function to get a ObsOutputType from a ObsOutputListType list.
  !!
  !<
  function get(this, indx) result(obsOutput)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    integer(I4B), intent(in) :: indx !< index for ObsOutputType object
    ! result
    type(obsoutputtype), pointer :: obsoutput
    !
    obsoutput => getobsoutputfromlist(this%ObsOutputs, indx)
    !
    ! -- return
    return
  end function get
 
  !> @ brief Clear a ObsOutputListType
  !!
  !!  Subroutine to clear a ObsOutputListType list.
  !!
  !<
  subroutine clear(this)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    !
    call this%ObsOutputs%Clear()
    !
    ! -- return
    return
  end subroutine clear
 
  !> @ brief Deallocate a ObsOutputListType
  !!
  !!  Subroutine to deallocate a ObsOutputListType list.
  !!
  !<
  subroutine deallocobsoutputlist(this)
    ! -- dummy
    class(obsoutputlisttype), intent(inout) :: this
    ! -- local
    integer :: i, n
    type(obsoutputtype), pointer :: obsoutput => null()
    !
    n = this%Count()
    do i = 1, n
      obsoutput => getobsoutputfromlist(this%ObsOutputs, i)
      !call obsoutput%DeallocObsOutput()
    end do
    !
    call this%ObsOutputs%Clear(.true.)
    !
    ! -- return
    return
  end subroutine deallocobsoutputlist
 
end module obsoutputlistmodule