kind.f90

Go to the documentation of this file.

!> @brief This module defines variable data types
!!
!! This module defines the precision of logical, integer, long integer,
!! and real data types used in MODFLOW 6 and are available to all other
!! modules.
!!
!<
module kindmodule
  use, intrinsic :: iso_fortran_env, only: i4b => int32, &
                                         &i8b => int64, &
                                         &lgp => int32, &
                                         &dp => real64
 
  implicit none
 
  public :: i4b, i8b, lgp, dp, write_kindinfo
 
contains
 
  !> @brief Write variable data types
    !!
    !! This subroutine writes the precision of logical, integer, long integer,
    !! and real data types used in MODFLOW 6.
    !!
  !<
  subroutine write_kindinfo(iout)
    ! -- dummy variables
    integer(I4B), intent(in) :: iout !< file unit to output kind variables
    ! -- local variables
    integer(LGP) :: ldum = 0
    integer(I4B) :: idum = 0
    integer(I8B) :: long_idum = 0
    integer(DP) :: irdum = 0 ! for bit size of real variables
    real(dp) :: rdum = 0._dp
    !
    ! -- write kind information
    write (iout, '(/a)') 'Real Variables'
    write (iout, '(2x,a,i0)') 'KIND: ', dp
    write (iout, '(2x,a,1pg15.6)') 'TINY (smallest non-zero value): ', &
      tiny(rdum)
    write (iout, '(2x,a,1pg15.6)') 'HUGE (largest value): ', huge(rdum)
    write (iout, '(2x,a,i0)') 'PRECISION: ', precision(rdum)
    write (iout, '(2x,a,i0)') 'SIZE IN BITS: ', bit_size(irdum)
 
    write (iout, '(/a)') 'Integer Variables'
    write (iout, '(2x,a,i0)') 'KIND: ', i4b
    write (iout, '(2x,a,i0)') 'HUGE (largest value): ', huge(idum)
    write (iout, '(2x,a,i0)') 'SIZE IN BITS: ', bit_size(idum)
 
    write (iout, '(/a)') 'Long Integer Variables'
    write (iout, '(2x,a,i0)') 'KIND: ', i8b
    write (iout, '(2x,a,i0)') 'HUGE (largest value): ', huge(long_idum)
    write (iout, '(2x,a,i0)') 'SIZE IN BITS: ', bit_size(long_idum)
 
    write (iout, '(/a)') 'Logical Variables'
    write (iout, '(2x,a,i0)') 'KIND: ', lgp
    write (iout, '(2x,a,i0)') 'SIZE IN BITS: ', bit_size(ldum)
  end subroutine write_kindinfo
 
end module kindmodule