ObsOutput.f90

Go to the documentation of this file.

!> @brief This module defines the derived type ObsOutputType
!!
!! This module contains information and methods needed for writing
!! a line of simulated values for observations to an output file.  Each
!! block of type continuous in an observation file is
!! associated with an ObsOutputType object. However, the methods are
!! needed only for continuous observations.
!!
!<
module obsoutputmodule
 
  use kindmodule, only: dp, i4b, lgp
  use constantsmodule, only: lenbigline, lenobsname
  use listmodule, only: listtype
 
  implicit none
 
  private
  public :: obsoutputtype, constructobsoutput, addobsoutputtolist, &
            getobsoutputfromlist
 
  type :: obsoutputtype
    ! -- Public members
    ! kind specified to ensure consistent binary output
    integer(kind=4), public :: nobs = 0 !< number of observations
    integer(I4B), public :: nunit = 0 !< observation output unit
    character(len=500), public :: filename = '' !< observation output filename
    logical(LGP), public :: empty_line = .true. !< logical indicating if the line for a time step is empty
    character(len=LENOBSNAME), public :: header = '' !< observation header string
    logical, public :: formattedoutput = .true. !< logical indicating if writing formatted output
  contains
    ! -- Public procedures
    procedure, public :: resetobsemptyline
    procedure, public :: writeobslinereturn
  end type obsoutputtype
 
contains
 
  ! Procedures bound to ObsOutputType
 
  !> @ brief Reset empty line logical
  !!
  !!  Subroutine to reset the empty line logical.
  !!
  !<
  subroutine resetobsemptyline(this)
    ! -- dummy
    class(obsoutputtype), intent(inout) :: this
    !
    this%empty_line = .true.
  end subroutine resetobsemptyline
 
  !> @ brief Write line return for observation
  !!
  !!  Subroutine to write a line return for a time step in an observation
  !!  output file.
  !!
  !<
  subroutine writeobslinereturn(this)
    ! -- dummy
    class(obsoutputtype), intent(inout) :: this
    ! -- write a line return to end of observation output line
    !    for this totim
    write (this%nunit, '(a)', advance='YES') ''
  end subroutine writeobslinereturn
 
  ! Non-type-bound procedures
 
  !> @ brief Cast as ObsOutputType
  !!
  !!  Cast an object as an ObsOutputType.
  !!
  !<
  function castasobsoutputtype(obj) result(res)
    ! -- dummy
    class(*), pointer, intent(inout) :: obj !< input object
    type(obsoutputtype), pointer :: res !< ObsOutputType
    !
    res => null()
    if (.not. associated(obj)) return
    !
    select type (obj)
    type is (obsoutputtype)
      res => obj
    class default
      continue
    end select
  end function castasobsoutputtype
 
  !> @ brief Construct and assign ObsOutputType object
  !!
  !!  Subroutine to construct an ObsOutputType object and assign
  !!  the observation output file name and unit number.
  !!
  !<
  subroutine constructobsoutput(newObsOutput, fname, nunit)
    ! -- dummy
    type(obsoutputtype), pointer, intent(out) :: newobsoutput
    character(len=*), intent(in) :: fname !< observation output file name
    integer(I4B), intent(in) :: nunit !< observation output unit number
    !
    allocate (newobsoutput)
    newobsoutput%filename = fname
    newobsoutput%nunit = nunit
  end subroutine constructobsoutput
 
  !> @ brief Add observation output to a list
  !!
  !!  Subroutine to add observation output to a observation list.
  !!
  !<
  subroutine addobsoutputtolist(list, obsOutput)
    ! -- dummy
    type(listtype), intent(inout) :: list !< observation list
    type(obsoutputtype), pointer, intent(inout) :: obsoutput !< observation output
    ! -- local
    class(*), pointer :: obj
    !
    obj => obsoutput
    call list%Add(obj)
  end subroutine addobsoutputtolist
 
  !> @ brief Get observation output from a list
  !!
  !!  Subroutine to get observation output from a observation list.
  !!
  !<
  function getobsoutputfromlist(list, idx) result(res)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list !< observation list
    integer(I4B), intent(in) :: idx !< observation index
    type(obsoutputtype), pointer :: res !< observation output
    ! -- local
    class(*), pointer :: obj
    !
    obj => list%GetItem(idx)
    res => castasobsoutputtype(obj)
  end function getobsoutputfromlist
 
end module obsoutputmodule