MemoryStore.f90

Go to the documentation of this file.

module memorystoremodule
  use kindmodule, only: i4b
  use memorytypemodule, only: memorytype
  use ptrhashtablemodule, only: ptrhashtabletype
  use iteratormodule, only: iteratortype
  use memorycontaineriteratormodule, only: memorycontaineriteratortype
  use memoryhelpermodule, only: create_mem_address
  use constantsmodule, only: lenmemaddress
 
  private
  public :: memorystoretype
 
  type :: memorystoretype
    private
    type(ptrhashtabletype) :: container
  contains
    procedure :: iterator
    procedure :: add
    procedure :: get
    procedure :: count
    procedure :: clear
  end type memorystoretype
 
contains
 
  !> @brief An iterator used to iterate through a MemoryContainer
  !!
  !<
  function iterator(this) result(itr)
    class(memorystoretype) :: this
    type(memorycontaineriteratortype) :: itr
    ! -- local
    class(iteratortype), allocatable :: container_iterator
 
    allocate (container_iterator, source=this%container%iterator())
    itr = memorycontaineriteratortype(container_iterator)
  end function
 
  !> @brief Add a MemoryType to the container
  !!
  !! The MemoryType is stored together with a key for easy lookup
  !! The key is constructed using the memory type's path and name
  !<
  subroutine add(this, mt)
    class(memorystoretype) :: this
    type(memorytype), pointer, intent(in) :: mt
    ! -- local
    class(*), pointer :: obj => null()
    character(len=LENMEMADDRESS) :: key
 
    key = create_mem_address(mt%path, mt%name)
    obj => mt
    call this%container%add(key, obj)
  end subroutine add
 
  !> @brief Get a MemoryType using a key
  !!
  !! If the key can't be found the return value will be a null pointer
  !<
  function get(this, name, path) result(mt)
    class(memorystoretype) :: this
    character(len=*), intent(in) :: name
    character(len=*), intent(in) :: path
    type(memorytype), pointer :: mt
    ! -- local
    character(len=LENMEMADDRESS) :: key
    class(*), pointer :: obj
 
    key = create_mem_address(path, name)
    obj => this%container%get(key)
 
    select type (obj)
    type is (memorytype)
      mt => obj
    class default
      mt => null()
    end select
 
  end function get
 
  !> @brief The nummer of items in the container
  !!
  !<
  function count(this) result(cnt)
    class(memorystoretype) :: this
    integer(I4B) :: cnt
 
    cnt = this%container%count()
  end function count
 
  !> @brief Clears the memory container
  !!
  !<
  subroutine clear(this)
    class(memorystoretype) :: this
 
    call this%container%clear()
  end subroutine clear
 
end module memorystoremodule