MemoryContainerIterator.f90

Go to the documentation of this file.

module memorycontaineriteratormodule
  use kindmodule, only: i4b, lgp
  use memorytypemodule, only: memorytype
  use iteratormodule, only: iteratortype
 
  implicit none
  private
 
  public :: memorycontaineriteratortype
 
  !> @brief An iterator used to iterate through a MemoryContainer
  !!
  !<
  type :: memorycontaineriteratortype
    private
    class(iteratortype), allocatable :: container_iterator !< the current iterator to the underlying container
  contains
    procedure :: has_next
    procedure :: next
    procedure :: value
  end type
 
  interface memorycontaineriteratortype
    module procedure constructor
  end interface memorycontaineriteratortype
 
contains
  !> @brief Constructor to create a MemoryContainerIterator
  !!
  !<
  function constructor(container_iterator) result(iterator)
    class(iteratortype), allocatable :: container_iterator
    type(memorycontaineriteratortype) :: iterator
 
    call move_alloc(container_iterator, iterator%container_iterator)
 
  end function constructor
 
  !> @brief Indicates if there is a next node in the iteration chain
  !!
  !<
  function has_next(this) result(res)
    class(memorycontaineriteratortype) :: this
    logical(LGP) :: res
 
    res = this%container_iterator%has_next()
  end function
 
  !> @brief Increment the iterator to the next node
  !!
  !<
  subroutine next(this)
    class(memorycontaineriteratortype) :: this
 
    call this%container_iterator%next()
  end subroutine
 
  !> @brief Get the value the iterator is pointing to
  !!
  !<
  function value(this) result(res)
    class(memorycontaineriteratortype), target :: this
    type(memorytype), pointer :: res
    ! -- local
    class(*), pointer :: obj !< void pointer to MemoryType
 
    obj => this%container_iterator%value()
 
    select type (obj)
    type is (memorytype)
      res => obj
    class default
      res => null()
    end select
 
  end function
 
end module memorycontaineriteratormodule