MethodCellPassToBot.f90

Go to the documentation of this file.

module methodcellpasstobotmodule
 
  use kindmodule, only: dp, i4b
  use methodmodule, only: methodtype
  use celldefnmodule, only: celldefntype, create_defn
  use prtfmimodule, only: prtfmitype
  use basedismodule, only: disbasetype
  use particlemodule, only: particletype
  use cellmodule, only: celltype
  use subcellmodule, only: subcelltype
  use trackmodule, only: trackfilecontroltype
  implicit none
 
  private
  public :: methodcellpasstobottype
  public :: create_method_cell_ptb
 
  type, extends(methodtype) :: methodcellpasstobottype
    private
    type(celldefntype), pointer :: defn
  contains
    procedure, public :: apply => apply_ptb
    procedure, public :: destroy
  end type methodcellpasstobottype
 
contains
 
  !> @brief Create a new tracking method
  subroutine create_method_cell_ptb(method)
    type(methodcellpasstobottype), pointer :: method
    allocate (method)
    allocate (method%type)
    method%type = "passtobottom"
    method%delegates = .false.
    call create_defn(method%defn)
  end subroutine create_method_cell_ptb
 
  !> @brief Destroy the tracking method
  subroutine destroy(this)
    class(methodcellpasstobottype), intent(inout) :: this
    deallocate (this%type)
  end subroutine destroy
 
  !> @brief Pass particle vertically and instantaneously to the cell bottom
  subroutine apply_ptb(this, particle, tmax)
    ! -- dummy
    class(methodcellpasstobottype), intent(inout) :: this
    type(particletype), pointer, intent(inout) :: particle
    real(DP), intent(in) :: tmax
 
    call this%update(particle, this%defn)
    if (.not. particle%advancing) return
    particle%z = this%defn%bot
    particle%iboundary(2) = this%defn%npolyverts + 2
    call this%save(particle, reason=1) ! reason=1: cell transition
  end subroutine apply_ptb
 
end module methodcellpasstobotmodule