TimeSeriesRecord.f90

Go to the documentation of this file.

module timeseriesrecordmodule
 
  use kindmodule, only: dp, i4b
  use listmodule, only: listtype
 
  private
  public :: timeseriesrecordtype, constructtimeseriesrecord, &
            castastimeseriesrecordtype, addtimeseriesrecordtolist
 
  type :: timeseriesrecordtype
    ! -- Public members
    real(dp), public :: tsrtime
    real(dp), public :: tsrvalue
  end type timeseriesrecordtype
 
contains
 
  !> @brief Allocate and assign members of a new TimeSeriesRecordType object
  !<
  subroutine constructtimeseriesrecord(newTsRecord, time, value)
    implicit none
    ! -- dummy
    type(timeseriesrecordtype), pointer, intent(out) :: newtsrecord
    real(dp), intent(in) :: time, value
    !
    allocate (newtsrecord)
    newtsrecord%tsrTime = time
    newtsrecord%tsrValue = value
    !
    ! -- Return
    return
  end subroutine constructtimeseriesrecord
 
  !> @brief Cast an unlimited polymorphic object as TimeSeriesRecordType
  !<
  function castastimeseriesrecordtype(obj) result(res)
    implicit none
    ! -- dummy
    class(*), pointer, intent(inout) :: obj
    ! -- return
    type(timeseriesrecordtype), pointer :: res
    !
    res => null()
    if (.not. associated(obj)) return
    !
    select type (obj)
    type is (timeseriesrecordtype)
      res => obj
    end select
    !
    ! -- Return
    return
  end function castastimeseriesrecordtype
 
  !> @brief Add time series record to list
  !<
  subroutine addtimeseriesrecordtolist(list, tsrecord)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list
    type(timeseriesrecordtype), pointer, intent(inout) :: tsrecord
    ! -- local
    class(*), pointer :: obj => null()
    !
    obj => tsrecord
    call list%Add(obj)
    !
    ! -- Return
    return
  end subroutine addtimeseriesrecordtolist
 
end module timeseriesrecordmodule