TimeSeriesLink.f90

Go to the documentation of this file.

module timeserieslinkmodule
 
  use kindmodule, only: dp, i4b
  use constantsmodule, only: dzero, lenboundname, lenpackagename, &
                             lentimeseriestext
  use inputoutputmodule, only: upcase
  use listmodule, only: listtype
  use timeseriesmodule, only: timeseriestype
 
  implicit none
 
  private
  public :: timeserieslinktype, constructtimeserieslink, &
            gettimeserieslinkfromlist, addtimeserieslinktolist
  private :: castastimeserieslinktype
 
  type :: timeserieslinktype
    ! -- Public members
    integer(I4B), public :: irow = 0 ! row index (2nd dim) in bound or auxval array
    integer(I4B), public :: jcol = 0 ! column index (1st dim) in bound or auxval array
    integer(I4B), public :: iprpak = 1
    ! BndElement can point to an element in either the bound or auxval
    ! array of BndType, or any other double precision variable or array
    ! element that contains a value that could be controlled by a time series.
    real(dp), pointer, public :: bndelement => null()
    real(dp), pointer, public :: rmultiplier => null()
    real(dp), public :: cellarea = dzero
    character(len=LENPACKAGENAME), public :: packagename = ''
    character(len=3), public :: auxorbnd = ''
    character(len=LENTIMESERIESTEXT), public :: text = ''
    character(len=LENBOUNDNAME), public :: bndname = ''
    logical, public :: active = .true.
    logical, public :: usedefaultproc = .true.
    logical, public :: convertflux = .false.
    type(timeseriestype), pointer, public :: timeseries => null()
  end type timeserieslinktype
 
contains
 
  !> @brief Construct time series link
  !<
  subroutine constructtimeserieslink(newTsLink, timeSeries, pkgName, &
                                     auxOrBnd, bndElem, iRow, jCol, iprpak, &
                                     text)
    implicit none
    ! -- dummy
    type(timeserieslinktype), pointer, intent(out) :: newtslink
    type(timeseriestype), pointer, intent(in) :: timeseries
    integer(I4B), intent(in) :: irow, jcol
    character(len=*), intent(in) :: pkgname
    character(len=3), intent(in) :: auxorbnd
    real(dp), pointer, intent(in) :: bndelem
    integer(I4B), intent(in) :: iprpak
    character(len=*), optional :: text
    ! -- local
    character(len=LENPACKAGENAME) :: pkgnametemp
    !
    allocate (newtslink)
    !
    ! Store package name as all caps
    pkgnametemp = pkgname
    call upcase(pkgnametemp)
    newtslink%PackageName = pkgnametemp
    newtslink%AuxOrBnd = auxorbnd
    newtslink%timeSeries => timeseries
    newtslink%iRow = irow
    newtslink%jCol = jcol
    newtslink%BndElement => bndelem
    newtslink%Iprpak = iprpak
    !
    if (present(text)) then
      newtslink%Text = text
    end if
  end subroutine constructtimeserieslink
 
  !> @brief Cast an unlimited polymorphic object as TimeSeriesLinkType
  !<
  function castastimeserieslinktype(obj) result(res)
    implicit none
    ! -- dummy
    class(*), pointer, intent(inout) :: obj
    ! -- return
    type(timeserieslinktype), pointer :: res
    !
    res => null()
    if (.not. associated(obj)) return
    !
    select type (obj)
    type is (timeserieslinktype)
      res => obj
    class default
      continue
    end select
  end function castastimeserieslinktype
 
  !> @brief Get time series link from a list
  !<
  function gettimeserieslinkfromlist(list, indx) result(tsLink)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list
    integer(I4B), intent(in) :: indx
    ! -- return
    type(timeserieslinktype), pointer :: tslink
    ! -- local
    class(*), pointer :: obj
    !
    tslink => null()
    obj => list%GetItem(indx)
    tslink => castastimeserieslinktype(obj)
  end function gettimeserieslinkfromlist
 
  !> @brief Add time series link to a list
  !<
  subroutine addtimeserieslinktolist(list, tslink)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list
    type(timeserieslinktype), pointer, intent(inout) :: tslink
    ! -- local
    class(*), pointer :: obj
    !
    obj => tslink
    call list%Add(obj)
  end subroutine addtimeserieslinktolist
 
end module timeserieslinkmodule