TimeSeriesFileList.f90

Go to the documentation of this file.

module timeseriesfilelistmodule
 
  use kindmodule, only: dp, i4b
  use constantsmodule, only: linelength
  use listmodule, only: listtype
  use timeseriesmodule, only: timeseriesfiletype, &
                              constructtimeseriesfile, &
                              gettimeseriesfilefromlist, &
                              addtimeseriesfiletolist
 
  implicit none
 
  private
  public :: timeseriesfilelisttype
 
  type :: timeseriesfilelisttype
    ! -- Public members
    integer(I4B), public :: numtsfiles = 0
    type(listtype), public :: tsfilelist
 
  contains
 
    ! -- Public procedures
    procedure, public :: add
    procedure, public :: counttsfiles
    procedure, public :: counttimeseries
    procedure, public :: gettsfile
    procedure, public :: clear
    procedure, public :: da => tsfl_da
    procedure, public :: add_time_series_tsfile
  end type timeseriesfilelisttype
 
contains
 
  ! -- Public procedures
 
  subroutine add(this, filename, iout, tsfile)
    implicit none
    ! -- dummy
    class(timeseriesfilelisttype), intent(inout) :: this
    character(len=*), intent(in) :: filename
    integer(I4B), intent(in) :: iout
    class(timeseriesfiletype), pointer, intent(inout) :: tsfile
    ! -- local
    type(timeseriesfiletype), pointer :: tsf
    !
    ! -- Construct and initialize a new time-series tsfile
    call constructtimeseriesfile(tsf)
    tsfile => tsf
    call tsfile%Initializetsfile(filename, iout, .true.)
    !
    ! -- Add the time-series tsfile to the list
    call this%add_time_series_tsfile(tsfile)
  end subroutine add
 
  subroutine clear(this)
    implicit none
    ! -- dummy
    class(timeseriesfilelisttype), intent(inout) :: this
    !
    call this%tsfileList%Clear()
  end subroutine clear
 
  function counttsfiles(this)
    implicit none
    ! -- return
    integer(I4B) :: counttsfiles
    ! -- dummy
    class(timeseriesfilelisttype) :: this
    !
    counttsfiles = this%tsfileList%Count()
    !
  end function counttsfiles
 
  function counttimeseries(this)
    implicit none
    ! -- return
    integer(I4B) :: counttimeseries
    ! -- dummy
    class(timeseriesfilelisttype) :: this
    ! -- local
    integer(I4B) :: i, numtsfiles
    type(timeseriesfiletype), pointer :: tsfile
    !
    numtsfiles = this%Counttsfiles()
    counttimeseries = 0
    do i = 1, numtsfiles
      tsfile => this%Gettsfile(i)
      if (associated(tsfile)) then
        counttimeseries = counttimeseries + tsfile%Count()
      end if
    end do
  end function counttimeseries
 
  function gettsfile(this, indx) result(res)
    implicit none
    ! -- dummy
    class(timeseriesfilelisttype) :: this
    integer(I4B), intent(in) :: indx
    ! -- return
    type(timeseriesfiletype), pointer :: res
    !
    res => gettimeseriesfilefromlist(this%tsfileList, indx)
  end function gettsfile
 
  ! -- Private procedures
 
  subroutine add_time_series_tsfile(this, tsfile)
    implicit none
    ! -- dummy
    class(timeseriesfilelisttype), intent(inout) :: this
    class(timeseriesfiletype), pointer, intent(inout) :: tsfile
    !
    call addtimeseriesfiletolist(this%tsfileList, tsfile)
    this%numtsfiles = this%numtsfiles + 1
  end subroutine add_time_series_tsfile
 
  subroutine tsfl_da(this)
    ! -- dummy
    class(timeseriesfilelisttype), intent(inout) :: this
    ! -- local
    integer(I4B) :: i, n
    type(timeseriesfiletype), pointer :: tsf => null()
    !
    n = this%Counttsfiles()
    do i = 1, n
      tsf => this%Gettsfile(i)
      call tsf%da()
    end do
    !
    call this%tsfileList%Clear(.true.)
    !
  end subroutine tsfl_da
 
end module timeseriesfilelistmodule