StringList.f90

Go to the documentation of this file.

module stringlistmodule
 
  use kindmodule, only: dp, i4b
  use listmodule, only: listtype
  use characterstringmodule, only: characterstringtype
 
  private
  public :: addstringtolist, getstringfromlist
 
contains
 
  subroutine constructcharactercontainer(newCharCont, text)
    implicit none
    type(characterstringtype), pointer, intent(out) :: newCharCont
    character(len=*), intent(in) :: text
    !
    allocate (newcharcont)
    newcharcont = text
  end subroutine constructcharactercontainer
 
  function castascharacterstringtype(obj) result(res)
    implicit none
    class(*), pointer, intent(inout) :: obj
    type(characterstringtype), pointer :: res
    !
    res => null()
    if (.not. associated(obj)) return
    !
    select type (obj)
    type is (characterstringtype)
      res => obj
    end select
  end function castascharacterstringtype
 
  subroutine addstringtolist(list, string)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list
    character(len=*), intent(in) :: string
    ! -- local
    class(*), pointer :: obj
    type(characterstringtype), pointer :: newcharactercontainer
    !
    newcharactercontainer => null()
    call constructcharactercontainer(newcharactercontainer, string)
    if (associated(newcharactercontainer)) then
      obj => newcharactercontainer
      call list%Add(obj)
    end if
  end subroutine addstringtolist
 
  function getstringfromlist(list, indx) result(string)
    implicit none
    ! -- dummy
    type(listtype), intent(inout) :: list
    integer(I4B), intent(in) :: indx
    character(len=:), allocatable :: string
    ! -- local
    class(*), pointer :: obj
    type(characterstringtype), pointer :: charcont
    !
    obj => list%GetItem(indx)
    charcont => castascharacterstringtype(obj)
    if (associated(charcont)) then
      allocate (character(len=charcont%strlen()) :: string)
      string(:) = charcont
    else
      string = ''
    end if
  end function getstringfromlist
 
end module stringlistmodule