RectangularGeometry.f90

Go to the documentation of this file.

module rectangulargeometrymodule
  use kindmodule, only: dp, i4b
  use basegeometrymodule, only: basegeometrytype
  use constantsmodule, only: dzero
  implicit none
  private
  public :: rectangulargeometrytype
 
  type, extends(basegeometrytype) :: rectangulargeometrytype
    real(dp) :: height = dzero
    real(dp) :: width = dzero
 
  contains
 
    procedure :: area_sat
    procedure :: perimeter_sat
    procedure :: area_wet
    procedure :: perimeter_wet
    procedure :: set_attribute
    procedure :: print_attributes
  end type rectangulargeometrytype
 
contains
 
  !> @brief Return saturated area
  !<
  function area_sat(this)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: area_sat
    ! -- dummy
    class(rectangulargeometrytype) :: this
    !
    ! -- Calculate area
    area_sat = this%height * this%width
  end function area_sat
 
  !> @brief Return saturated perimeter
  !<
  function perimeter_sat(this)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: perimeter_sat
    ! -- dummy
    class(rectangulargeometrytype) :: this
    !
    ! -- Calculate area
    perimeter_sat = dtwo * (this%height + this%width)
  end function perimeter_sat
 
  !> @brief Return wetted area
  !<
  function area_wet(this, depth)
    ! -- modules
    use constantsmodule, only: dtwo, dpi, dzero
    ! -- return
    real(dp) :: area_wet
    ! -- dummy
    class(rectangulargeometrytype) :: this
    real(dp), intent(in) :: depth
    !
    ! -- Calculate area
    if (depth <= dzero) then
      area_wet = dzero
    elseif (depth <= this%height) then
      area_wet = depth * this%width
    else
      area_wet = this%width * this%height
    end if
  end function area_wet
 
  !> @brief Return wetted perimeter
  !<
  function perimeter_wet(this, depth)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: perimeter_wet
    ! -- dummy
    class(rectangulargeometrytype) :: this
    real(dp), intent(in) :: depth
    !
    ! -- Calculate area
    if (depth <= dzero) then
      perimeter_wet = dzero
    elseif (depth <= this%height) then
      perimeter_wet = dtwo * (depth + this%width)
    else
      perimeter_wet = dtwo * (this%height + this%width)
    end if
  end function perimeter_wet
 
  !> @brief Set a parameter for this rectangular object
  !<
  subroutine set_attribute(this, line)
    ! -- module
    use inputoutputmodule, only: urword
    use constantsmodule, only: linelength
    use simmodule, only: store_error, count_errors
    ! -- dummy
    class(rectangulargeometrytype) :: this
    character(len=LINELENGTH) :: errmsg
    character(len=*), intent(inout) :: line
    ! -- local
    integer(I4B) :: lloc, istart, istop, ival
    real(DP) :: rval
    !
    ! -- should change this and set id if uninitialized or store it
    lloc = 1
    call urword(line, lloc, istart, istop, 2, ival, rval, 0, 0)
    this%id = ival
    !
    ! -- Parse the attribute
    call urword(line, lloc, istart, istop, 1, ival, rval, 0, 0)
    select case (line(istart:istop))
    case ('NAME')
      call urword(line, lloc, istart, istop, 1, ival, rval, 0, 0)
      this%name = line(istart:istop)
    case ('HEIGHT')
      call urword(line, lloc, istart, istop, 3, ival, rval, 0, 0)
      this%height = rval
    case ('WIDTH')
      call urword(line, lloc, istart, istop, 3, ival, rval, 0, 0)
      this%width = rval
    case default
      write (errmsg, '(a,a)') &
        'Unknown rectangular geometry attribute: ', line(istart:istop)
      call store_error(errmsg, terminate=.true.)
    end select
  end subroutine set_attribute
 
  !> @brief Print the attributes for this object
  !<
  subroutine print_attributes(this, iout)
    ! -- dummy
    class(rectangulargeometrytype) :: this
    ! -- local
    integer(I4B), intent(in) :: iout
    ! -- formats
    character(len=*), parameter :: fmtnm = "(4x,a,a)"
    character(len=*), parameter :: fmttd = "(4x,a,1(1PG15.6))"
    !
    ! -- call parent to print parent attributes
    call this%BaseGeometryType%print_attributes(iout)
    !
    ! -- Print specifics of this geometry type
    write (iout, fmttd) 'HEIGHT = ', this%height
    write (iout, fmttd) 'WIDTH = ', this%width
    write (iout, fmttd) 'SATURATED AREA = ', this%area_sat()
    write (iout, fmttd) 'SATURATED WETTED PERIMETER = ', this%perimeter_sat()
  end subroutine print_attributes
 
end module rectangulargeometrymodule