PtrHashTableIterator.f90

Go to the documentation of this file.

module ptrhashtableiteratormodule
  use keyvaluelistmodule, only: keyvaluelisttype
  use kindmodule, only: i4b
  use iteratormodule, only: iteratortype
 
  implicit none
  private
 
  public :: ptrhashtableiteratortype
 
  !> @brief An iterator used to iterate through a PtrHashTable
  !!
  !<
  type, extends(iteratortype) :: ptrhashtableiteratortype
    type(keyvaluelisttype), pointer :: buckets(:) => null() !< the buckets of the PtrHashTable to iterate through
    class(iteratortype), allocatable :: current_bucket_iterator !< the iterator of the bucket to which the current iterator belongs
    integer(I4B) :: curent_bucket_index = 1 !< the bucket in which the current iterator belongs
  contains
    procedure :: has_next
    procedure :: next
    procedure :: value
  end type
 
  interface ptrhashtableiteratortype
    module procedure constructor
  end interface ptrhashtableiteratortype
 
contains
  !> @brief Constructor to create a PtrHashTableIterator
  !!
  !<
  function constructor(buckets) Result(iterator)
    type(keyvaluelisttype), target, dimension(:), intent(in) :: buckets
    type(ptrhashtableiteratortype) :: iterator
    ! -- local
    type(keyvaluelisttype), pointer :: first_bucket
 
    iterator%buckets => buckets
 
    first_bucket => iterator%buckets(1)
    allocate (iterator%current_bucket_iterator, source=first_bucket%iterator())
 
  end function constructor
 
  !> @brief Indicates if there is a next node in the iteration chain
  !!
  !<
  function has_next(this) result(res)
    class(ptrhashtableiteratortype) :: this
    type(logical) :: res
    ! -- local
    type(keyvaluelisttype), pointer :: bucket
    integer(I4B) :: bucket_index
 
    !
    ! -- check if there are more values in the current bucket
    if (this%current_bucket_iterator%has_next()) then
      res = .true.
      return
    end if
 
    !
    ! -- check if there is a next bucket which has values.
    ! -- if so then there is more to iterate through.
    do bucket_index = this%curent_bucket_index + 1, size(this%buckets)
      bucket => this%buckets(bucket_index)
      if (bucket%count() > 0) then
        res = .true.
        return
      end if
    end do
 
    res = .false.
 
  end function
 
  !> @brief Increment the iterator to the next node
  !!
  !<
  subroutine next(this)
    class(ptrhashtableiteratortype) :: this
    ! -- local
    type(keyvaluelisttype), pointer :: bucket !< a bucket
    integer(I4B) :: bucket_index
 
    !
    ! -- If the current bucket doesn't have anymore values continue to the next
    if (.not. this%current_bucket_iterator%has_next()) then
      do bucket_index = this%curent_bucket_index + 1, size(this%buckets)
        bucket => this%buckets(bucket_index)
        if (bucket%count() > 0) then
          deallocate (this%current_bucket_iterator)
          allocate (this%current_bucket_iterator, source=bucket%iterator())
          this%curent_bucket_index = bucket_index
          exit
        end if
      end do
    end if
 
    call this%current_bucket_iterator%next()
 
  end subroutine
 
  !> @brief Get the value the iterator is pointing to
  !!
  !<
  function value(this) result(res)
    class(ptrhashtableiteratortype) :: this
    class(*), pointer :: res
 
    res => this%current_bucket_iterator%value()
 
  end function
 
end module ptrhashtableiteratormodule