KeyValueListIterator.f90

Go to the documentation of this file.

module keyvaluelistiteratormodule
  use kindmodule, only: i4b
  use keyvaluenodemodule, only: keyvaluenodetype
  use iteratormodule, only: iteratortype
 
  !> @brief An iterator used to iterate through a KeyValueList
  !!
  !<
  type, extends(iteratortype) :: keyvaluelistiteratortype
    private
    type(keyvaluenodetype), pointer :: first_node => null() !< the KeyValueList to iterate through
    type(keyvaluenodetype), pointer :: current_node => null() !< the current node in the list the iterator is pointing to
  contains
    procedure :: has_next
    procedure :: next
    procedure :: value
  end type
 
  interface keyvaluelistiteratortype
    module procedure constructor
  end interface keyvaluelistiteratortype
 
contains
 
  !> @brief Constructor to create a KeyValueListIterator
  !!
  !<
  function constructor(first_node) Result(iterator)
    type(keyvaluenodetype), pointer, intent(in) :: first_node
    type(keyvaluelistiteratortype) :: iterator
 
    iterator%first_node => first_node
    iterator%current_node => null()
 
  end function constructor
 
  !> @brief Indicates if there is a next node in the iteration chain
  !!
  !<
  function has_next(this) result(res)
    class(keyvaluelistiteratortype) :: this
    type(logical) :: res
 
    if (associated(this%current_node)) then
      res = associated(this%current_node%next)
    else
      res = associated(this%first_node)
    end if
 
  end function
 
  !> @brief Increment the iterator to the next node
  !!
  !<
  subroutine next(this)
    class(keyvaluelistiteratortype) :: this
 
    if (associated(this%current_node)) then
      this%current_node => this%current_node%next
    else
      this%current_node => this%first_node
    end if
  end subroutine
 
  !> @brief Get the value the iterator is pointing at
  !!
  !<
  function value(this) result(res)
    class(keyvaluelistiteratortype) :: this
    class(*), pointer :: res
 
    if (associated(this%current_node)) then
      res => this%current_node%value
    else
      res => null()
    end if
 
  end function
 
end module keyvaluelistiteratormodule