CircularGeometry.f90

Go to the documentation of this file.

module circulargeometrymodule
  use kindmodule, only: dp, i4b
  use basegeometrymodule, only: basegeometrytype
  use constantsmodule, only: dzero
 
  implicit none
 
  private
  public :: circulargeometrytype
 
  type, extends(basegeometrytype) :: circulargeometrytype
    real(dp) :: radius = dzero
 
  contains
 
    procedure :: area_sat
    procedure :: perimeter_sat
    procedure :: area_wet
    procedure :: perimeter_wet
    procedure :: set_attribute
    procedure :: print_attributes
  end type circulargeometrytype
 
contains
 
  !> @brief Return area as if geometry is fully saturated
  !<
  function area_sat(this)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: area_sat
    ! -- dummy
    class(circulargeometrytype) :: this
    !
    ! -- Calculate area
    area_sat = dpi * this%radius**dtwo
  end function area_sat
 
  !> @brief Return perimeter as if geometry is fully saturated
  !<
  function perimeter_sat(this)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: perimeter_sat
    ! -- dummy
    class(circulargeometrytype) :: this
    !
    ! -- Calculate area
    perimeter_sat = dtwo * dpi * this%radius
  end function perimeter_sat
 
  !> @brief Return wetted area
  !<
  function area_wet(this, depth)
    ! -- modules
    use constantsmodule, only: dtwo, dpi, dzero
    ! -- return
    real(dp) :: area_wet
    ! -- dummy
    class(circulargeometrytype) :: this
    real(dp), intent(in) :: depth
    !
    ! -- Calculate area
    if (depth <= dzero) then
      area_wet = dzero
    elseif (depth <= this%radius) then
      area_wet = this%radius * this%radius * &
                 acos((this%radius - depth) / this%radius) - &
                 (this%radius - depth) * &
                 sqrt(this%radius * this%radius - (this%radius - depth)**dtwo)
    elseif (depth <= dtwo * this%radius) then
      area_wet = this%radius * this%radius * &
                 (dpi - acos((depth - this%radius) / this%radius)) - &
                 (this%radius - depth) * &
                 sqrt(this%radius * this%radius - (this%radius - depth)**dtwo)
    else
      area_wet = dpi * this%radius * this%radius
    end if
  end function area_wet
 
  !> @brief Return wetted perimeter
  !<
  function perimeter_wet(this, depth)
    ! -- modules
    use constantsmodule, only: dtwo, dpi
    ! -- return
    real(dp) :: perimeter_wet
    ! -- dummy
    class(circulargeometrytype) :: this
    real(dp), intent(in) :: depth
    !
    ! -- Calculate area
    if (depth <= dzero) then
      perimeter_wet = dzero
    elseif (depth <= this%radius) then
      perimeter_wet = dtwo * this%radius * acos((this%radius - depth) / &
                                                this%radius)
    elseif (depth <= dtwo * this%radius) then
      perimeter_wet = dtwo * this%radius * (dpi - acos((depth - this%radius) / &
                                                       this%radius))
    else
      perimeter_wet = dtwo * dpi * this%radius
    end if
  end function perimeter_wet
 
  !> @brief Set a parameter for this circular object
  !<
  subroutine set_attribute(this, line)
    ! -- module
    use inputoutputmodule, only: urword
    use constantsmodule, only: linelength
    use simmodule, only: store_error, count_errors
    ! -- dummy
    class(circulargeometrytype) :: this
    character(len=LINELENGTH) :: errmsg
    character(len=*), intent(inout) :: line
    ! -- local
    integer(I4B) :: lloc, istart, istop, ival
    real(DP) :: rval
    !
    ! -- should change this and set id if uninitialized or store it
    lloc = 1
    call urword(line, lloc, istart, istop, 2, ival, rval, 0, 0)
    this%id = ival
 
    ! -- Parse the attribute
    call urword(line, lloc, istart, istop, 1, ival, rval, 0, 0)
    select case (line(istart:istop))
    case ('NAME')
      call urword(line, lloc, istart, istop, 1, ival, rval, 0, 0)
      this%name = line(istart:istop)
    case ('RADIUS')
      call urword(line, lloc, istart, istop, 3, ival, rval, 0, 0)
      this%radius = rval
    case default
      write (errmsg, '(a,a)') &
        'Unknown circular geometry attribute: ', line(istart:istop)
      call store_error(errmsg, terminate=.true.)
    end select
  end subroutine set_attribute
 
  !> @brief Print the attributes for this object
  !<
  subroutine print_attributes(this, iout)
    ! -- dummy
    class(circulargeometrytype) :: this
    ! -- local
    integer(I4B), intent(in) :: iout
    ! -- formats
    character(len=*), parameter :: fmtnm = "(4x,a,a)"
    character(len=*), parameter :: fmttd = "(4x,a,1(1PG15.6))"
    !
    ! -- call parent to print parent attributes
    call this%BaseGeometryType%print_attributes(iout)
    !
    ! -- Print specifics of this geometry type
    write (iout, fmttd) 'RADIUS = ', this%radius
    write (iout, fmttd) 'SATURATED AREA = ', this%area_sat()
    write (iout, fmttd) 'SATURATED WETTED PERIMETER = ', this%perimeter_sat()
  end subroutine print_attributes
 
end module circulargeometrymodule