Data Types
type	gwtuzttype

Functions/Subroutines
subroutine, public	uzt_create (packobj, id, ibcnum, inunit, iout, namemodel, pakname, fmi, eqnsclfac, dvt, dvu, dvua)
	Create a new UZT package. More...

subroutine	find_uzt_package (this)
	Find corresponding uzt package. More...

subroutine	uzt_fc_expanded (this, rhs, ia, idxglo, matrix_sln)
	Add matrix terms related to UZT. More...

subroutine	uzt_solve (this)
	Explicit solve. More...

integer(i4b) function	uzt_get_nbudterms (this)
	Function that returns the number of budget terms for this package. More...

real(dp) function, dimension(:), pointer, contiguous	get_mvr_depvar (this)
	Override similarly named function in APT. More...

subroutine	uzt_setup_budobj (this, idx)
	Set up the budget object that stores all the unsaturated-zone flows. More...

subroutine	uzt_fill_budobj (this, idx, x, flowja, ccratin, ccratout)
	Copy flow terms into thisbudobj. More...

subroutine	allocate_scalars (this)
	Allocate scalar variables for package. More...

subroutine	uzt_allocate_arrays (this)
	Allocate arrays for package. More...

subroutine	uzt_da (this)
	Deallocate memory. More...

subroutine	uzt_infl_term (this, ientry, n1, n2, rrate, rhsval, hcofval)
	Infiltration term. More...

subroutine	uzt_rinf_term (this, ientry, n1, n2, rrate, rhsval, hcofval)
	Rejected infiltration term. More...

subroutine	uzt_uzet_term (this, ientry, n1, n2, rrate, rhsval, hcofval)
	Evapotranspiration from the unsaturated-zone term. More...

subroutine	uzt_ritm_term (this, ientry, n1, n2, rrate, rhsval, hcofval)
	Rejected infiltration to MVR/MVT term. More...

subroutine	uzt_df_obs (this)
	Define UZT Observation. More...

subroutine	uzt_rp_obs (this, obsrv, found)
	Process package specific obs. More...

subroutine	uzt_bd_obs (this, obstypeid, jj, v, found)
	Calculate observation value and pass it back to APT. More...

subroutine	uzt_set_stressperiod (this, itemno, keyword, found)
	Sets the stress period attributes for keyword use. More...

Variables
character(len= *), parameter	ftype = 'UZT'

character(len= *), parameter	flowtype = 'UZF'

character(len=16)	text = ' UZT'

Function/Subroutine Documentation

◆ allocate_scalars()

subroutine gwtuztmodule::allocate_scalars ( class(gwtuzttype) this )

Method to allocate scalar variables for the package.

Definition at line 532 of file gwt-uzt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_allocate
     ! -- dummy
     class(GwtUztType) :: this
     ! -- local
     !
     ! -- allocate scalars in TspAptType
     call this%TspAptType%allocate_scalars()
     !
     ! -- Allocate
     call mem_allocate(this%idxbudinfl, 'IDXBUDINFL', this%memoryPath)
     call mem_allocate(this%idxbudrinf, 'IDXBUDRINF', this%memoryPath)
     call mem_allocate(this%idxbuduzet, 'IDXBUDUZET', this%memoryPath)
     call mem_allocate(this%idxbudritm, 'IDXBUDRITM', this%memoryPath)
     !
     ! -- Initialize
     this%idxbudinfl = 0
     this%idxbudrinf = 0
     this%idxbuduzet = 0
     this%idxbudritm = 0

◆ find_uzt_package()

subroutine gwtuztmodule::find_uzt_package ( class(gwtuzttype) this )

Definition at line 138 of file gwt-uzt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_allocate
     ! -- dummy
     class(GwtUztType) :: this
     ! -- local
     character(len=LINELENGTH) :: errmsg
     class(BndType), pointer :: packobj
     integer(I4B) :: ip, icount
     integer(I4B) :: nbudterm
     logical :: found
     !
     ! -- Initialize found to false, and error later if flow package cannot
     !    be found
     found = .false.
     !
     ! -- If user is specifying flows in a binary budget file, then set up
     !    the budget file reader, otherwise set a pointer to the flow package
     !    budobj
     if (this%fmi%flows_from_file) then
       call this%fmi%set_aptbudobj_pointer(this%flowpackagename, this%flowbudptr)
       if (associated(this%flowbudptr)) found = .true.
       !
     else
       if (associated(this%fmi%gwfbndlist)) then
         ! -- Look through gwfbndlist for a flow package with the same name as
         !    this transport package name
         do ip = 1, this%fmi%gwfbndlist%Count()
           packobj => getbndfromlist(this%fmi%gwfbndlist, ip)
           if (packobj%packName == this%flowpackagename) then
             found = .true.
             !
             ! -- store BndType pointer to packobj, and then
             !    use the select type to point to the budobj in flow package
             this%flowpackagebnd => packobj
             select type (packobj)
             type is (uzftype)
               this%flowbudptr => packobj%budobj
             end select
           end if
           if (found) exit
         end do
       end if
     end if
     !
     ! -- error if flow package not found
     if (.not. found) then
       write (errmsg, '(a)') 'Could not find flow package with name '&
                             &//trim(adjustl(this%flowpackagename))//'.'
       call store_error(errmsg)
       call this%parser%StoreErrorUnit()
     end if
     !
     ! -- allocate space for idxbudssm, which indicates whether this is a
     !    special budget term or one that is a general source and sink
     nbudterm = this%flowbudptr%nbudterm
     call mem_allocate(this%idxbudssm, nbudterm, 'IDXBUDSSM', this%memoryPath)
     !
     ! -- Process budget terms and identify special budget terms
     write (this%iout, '(/, a, a)') &
       'PROCESSING '//ftype//' INFORMATION FOR ', this%packName
     write (this%iout, '(a)') '  IDENTIFYING FLOW TERMS IN '//flowtype//' PACKAGE'
     write (this%iout, '(a, i0)') &
       '  NUMBER OF '//flowtype//' = ', this%flowbudptr%ncv
     icount = 1
     do ip = 1, this%flowbudptr%nbudterm
       select case (trim(adjustl(this%flowbudptr%budterm(ip)%flowtype)))
       case ('FLOW-JA-FACE')
         this%idxbudfjf = ip
         this%idxbudssm(ip) = 0
       case ('GWF')
         this%idxbudgwf = ip
         this%idxbudssm(ip) = 0
       case ('STORAGE')
         this%idxbudsto = ip
         this%idxbudssm(ip) = 0
       case ('INFILTRATION')
         this%idxbudinfl = ip
         this%idxbudssm(ip) = 0
       case ('REJ-INF')
         this%idxbudrinf = ip
         this%idxbudssm(ip) = 0
       case ('UZET')
         this%idxbuduzet = ip
         this%idxbudssm(ip) = 0
       case ('REJ-INF-TO-MVR')
         this%idxbudritm = ip
         this%idxbudssm(ip) = 0
       case ('TO-MVR')
         this%idxbudtmvr = ip
         this%idxbudssm(ip) = 0
       case ('FROM-MVR')
         this%idxbudfmvr = ip
         this%idxbudssm(ip) = 0
       case ('AUXILIARY')
         this%idxbudaux = ip
         this%idxbudssm(ip) = 0
       case default
         !
         ! -- set idxbudssm equal to a column index for where the concentrations
         !    are stored in the concbud(nbudssm, ncv) array
         this%idxbudssm(ip) = icount
         icount = icount + 1
       end select
       write (this%iout, '(a, i0, " = ", a,/, a, i0)') &
         '  TERM ', ip, trim(adjustl(this%flowbudptr%budterm(ip)%flowtype)), &
         '   MAX NO. OF ENTRIES = ', this%flowbudptr%budterm(ip)%maxlist
     end do
     write (this%iout, '(a, //)') 'DONE PROCESSING '//ftype//' INFORMATION'

Here is the call graph for this function:

◆ get_mvr_depvar()

real(dp) function, dimension(:), pointer, contiguous gwtuztmodule::get_mvr_depvar ( class(gwtuzttype) this )

Set the concentration to be used by MVT as the user-specified concentration applied to the infiltration

Definition at line 385 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     ! -- return
     real(dp), dimension(:), contiguous, pointer :: get_mvr_depvar
     !
     get_mvr_depvar => this%concinfl

◆ uzt_allocate_arrays()

subroutine gwtuztmodule::uzt_allocate_arrays ( class(gwtuzttype), intent(inout) this )

Method to allocate arrays for the package.

Definition at line 559 of file gwt-uzt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_allocate
     ! -- dummy
     class(GwtUztType), intent(inout) :: this
     ! -- local
     integer(I4B) :: n
     !
     ! -- time series
     call mem_allocate(this%concinfl, this%ncv, 'CONCINFL', this%memoryPath)
     call mem_allocate(this%concuzet, this%ncv, 'CONCUZET', this%memoryPath)
     !
     ! -- call standard TspAptType allocate arrays
     call this%TspAptType%apt_allocate_arrays()
     !
     ! -- Initialize
     do n = 1, this%ncv
       this%concinfl(n) = dzero
       this%concuzet(n) = dzero
     end do

◆ uzt_bd_obs()

subroutine gwtuztmodule::uzt_bd_obs	(	class(gwtuzttype), intent(inout)	this,
		character(len=*), intent(in)	obstypeid,
		integer(i4b), intent(in)	jj,
		real(dp), intent(inout)	v,
		logical, intent(inout)	found
	)

Definition at line 837 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType), intent(inout) :: this
     character(len=*), intent(in) :: obstypeid
     real(DP), intent(inout) :: v
     integer(I4B), intent(in) :: jj
     logical, intent(inout) :: found
     ! -- local
     integer(I4B) :: n1, n2
     !
     found = .true.
     select case (obstypeid)
     case ('INFILTRATION')
       if (this%iboundpak(jj) /= 0 .and. this%idxbudinfl > 0) then
         call this%uzt_infl_term(jj, n1, n2, v)
       end if
     case ('REJ-INF')
       if (this%iboundpak(jj) /= 0 .and. this%idxbudrinf > 0) then
         call this%uzt_rinf_term(jj, n1, n2, v)
       end if
     case ('UZET')
       if (this%iboundpak(jj) /= 0 .and. this%idxbuduzet > 0) then
         call this%uzt_uzet_term(jj, n1, n2, v)
       end if
     case ('REJ-INF-TO-MVR')
       if (this%iboundpak(jj) /= 0 .and. this%idxbudritm > 0) then
         call this%uzt_ritm_term(jj, n1, n2, v)
       end if
     case default
       found = .false.
     end select

◆ uzt_create()

subroutine, public gwtuztmodule::uzt_create	(	class(bndtype), pointer	packobj,
		integer(i4b), intent(in)	id,
		integer(i4b), intent(in)	ibcnum,
		integer(i4b), intent(in)	inunit,
		integer(i4b), intent(in)	iout,
		character(len=*), intent(in)	namemodel,
		character(len=*), intent(in)	pakname,
		type(tspfmitype), pointer	fmi,
		real(dp), intent(in), pointer	eqnsclfac,
		character(len=*), intent(in)	dvt,
		character(len=*), intent(in)	dvu,
		character(len=*), intent(in)	dvua
	)

Parameters

[in]	eqnsclfac	governing equation scale factor
[in]	dvt	For GWT, set to "CONCENTRATION" in TspAptType
[in]	dvu	For GWT, set to "mass" in TspAptType
[in]	dvua	For GWT, set to "M" in TspAptType

Definition at line 83 of file gwt-uzt.f90.

     ! -- dummy
     class(BndType), pointer :: packobj
     integer(I4B), intent(in) :: id
     integer(I4B), intent(in) :: ibcnum
     integer(I4B), intent(in) :: inunit
     integer(I4B), intent(in) :: iout
     character(len=*), intent(in) :: namemodel
     character(len=*), intent(in) :: pakname
     type(TspFmiType), pointer :: fmi
     real(DP), intent(in), pointer :: eqnsclfac !< governing equation scale factor
     character(len=*), intent(in) :: dvt !< For GWT, set to "CONCENTRATION" in TspAptType
     character(len=*), intent(in) :: dvu !< For GWT, set to "mass" in TspAptType
     character(len=*), intent(in) :: dvua !< For GWT, set to "M" in TspAptType
     ! -- local
     type(GwtUztType), pointer :: uztobj
     !
     ! -- allocate the object and assign values to object variables
     allocate (uztobj)
     packobj => uztobj
     !
     ! -- create name and memory path
     call packobj%set_names(ibcnum, namemodel, pakname, ftype)
     packobj%text = text
     !
     ! -- allocate scalars
     call uztobj%allocate_scalars()
     !
     ! -- initialize package
     call packobj%pack_initialize()
     !
     packobj%inunit = inunit
     packobj%iout = iout
     packobj%id = id
     packobj%ibcnum = ibcnum
     packobj%ncolbnd = 1
     packobj%iscloc = 1
     !
     ! -- Store pointer to flow model interface.  When the GwfGwt exchange is
     !    created, it sets fmi%bndlist so that the GWT model has access to all
     !    the flow packages
     uztobj%fmi => fmi
     !
     ! -- Store pointer to governing equation scale factor
     uztobj%eqnsclfac => eqnsclfac
     !
     ! -- Set labels that will be used in generalized APT class
     uztobj%depvartype = dvt
     uztobj%depvarunit = dvu
     uztobj%depvarunitabbrev = dvua

Here is the caller graph for this function:

◆ uzt_da()

subroutine gwtuztmodule::uzt_da ( class(gwtuzttype) this )

Method to deallocate memory for the package.

Definition at line 585 of file gwt-uzt.f90.

     ! -- modules
     use memorymanagermodule, only: mem_deallocate
     ! -- dummy
     class(GwtUztType) :: this
     ! -- local
     !
     ! -- deallocate scalars
     call mem_deallocate(this%idxbudinfl)
     call mem_deallocate(this%idxbudrinf)
     call mem_deallocate(this%idxbuduzet)
     call mem_deallocate(this%idxbudritm)
     !
     ! -- deallocate time series
     call mem_deallocate(this%concinfl)
     call mem_deallocate(this%concuzet)
     !
     ! -- deallocate scalars in TspAptType
     call this%TspAptType%bnd_da()

◆ uzt_df_obs()

subroutine gwtuztmodule::uzt_df_obs ( class(gwtuzttype) this )

This subroutine:

Stores observation types supported by the parent APT package.
Overrides BndTypebnd_df_obs

Definition at line 747 of file gwt-uzt.f90.

     ! -- modules
     ! -- dummy
     class(GwtUztType) :: this
     ! -- local
     integer(I4B) :: indx
     !
     ! -- Store obs type and assign procedure pointer
     !    for concentration observation type.
     call this%obs%StoreObsType('concentration', .false., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for flow between uzt cells.
     call this%obs%StoreObsType('flow-ja-face', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid12
     !
     ! -- Store obs type and assign procedure pointer
     !    for from-mvr observation type.
     call this%obs%StoreObsType('from-mvr', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- to-mvr not supported for uzt
     !call this%obs%StoreObsType('to-mvr', .true., indx)
     !this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsID
     !
     ! -- Store obs type and assign procedure pointer
     !    for storage observation type.
     call this%obs%StoreObsType('storage', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for constant observation type.
     call this%obs%StoreObsType('constant', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for observation type: uzt
     call this%obs%StoreObsType('uzt', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for observation type.
     call this%obs%StoreObsType('infiltration', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for observation type.
     call this%obs%StoreObsType('rej-inf', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for observation type.
     call this%obs%StoreObsType('uzet', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid
     !
     ! -- Store obs type and assign procedure pointer
     !    for observation type.
     call this%obs%StoreObsType('rej-inf-to-mvr', .true., indx)
     this%obs%obsData(indx)%ProcessIdPtr => apt_process_obsid

Here is the call graph for this function:

◆ uzt_fc_expanded()

subroutine gwtuztmodule::uzt_fc_expanded	(	class(gwtuzttype)	this,
		real(dp), dimension(:), intent(inout)	rhs,
		integer(i4b), dimension(:), intent(in)	ia,
		integer(i4b), dimension(:), intent(in)	idxglo,
		class(matrixbasetype), pointer	matrix_sln
	)

This will be called from TspAptTypeapt_fc_expanded() in order to add matrix terms specifically for this package

Definition at line 254 of file gwt-uzt.f90.

     ! -- modules
     ! -- dummy
     class(GwtUztType) :: this
     real(DP), dimension(:), intent(inout) :: rhs
     integer(I4B), dimension(:), intent(in) :: ia
     integer(I4B), dimension(:), intent(in) :: idxglo
     class(MatrixBaseType), pointer :: matrix_sln
     ! -- local
     integer(I4B) :: j, n1, n2
     integer(I4B) :: iloc
     integer(I4B) :: iposd
     real(DP) :: rrate
     real(DP) :: rhsval
     real(DP) :: hcofval
     !
     ! -- add infiltration contribution
     if (this%idxbudinfl /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudinfl)%nlist
         call this%uzt_infl_term(j, n1, n2, rrate, rhsval, hcofval)
         iloc = this%idxlocnode(n1)
         iposd = this%idxpakdiag(n1)
         call matrix_sln%add_value_pos(iposd, hcofval)
         rhs(iloc) = rhs(iloc) + rhsval
       end do
     end if
     !
     ! -- add rejected infiltration contribution
     if (this%idxbudrinf /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudrinf)%nlist
         call this%uzt_rinf_term(j, n1, n2, rrate, rhsval, hcofval)
         iloc = this%idxlocnode(n1)
         iposd = this%idxpakdiag(n1)
         call matrix_sln%add_value_pos(iposd, hcofval)
         rhs(iloc) = rhs(iloc) + rhsval
       end do
     end if
     !
     ! -- add unsaturated et contribution
     if (this%idxbuduzet /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbuduzet)%nlist
         call this%uzt_uzet_term(j, n1, n2, rrate, rhsval, hcofval)
         iloc = this%idxlocnode(n1)
         iposd = this%idxpakdiag(n1)
         call matrix_sln%add_value_pos(iposd, hcofval)
         rhs(iloc) = rhs(iloc) + rhsval
       end do
     end if
     !
     ! -- add rejected infiltration to mover contribution
     if (this%idxbudritm /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudritm)%nlist
         call this%uzt_ritm_term(j, n1, n2, rrate, rhsval, hcofval)
         iloc = this%idxlocnode(n1)
         iposd = this%idxpakdiag(n1)
         call matrix_sln%add_value_pos(iposd, hcofval)
         rhs(iloc) = rhs(iloc) + rhsval
       end do
     end if

◆ uzt_fill_budobj()

subroutine gwtuztmodule::uzt_fill_budobj	(	class(gwtuzttype)	this,
		integer(i4b), intent(inout)	idx,
		real(dp), dimension(:), intent(in)	x,
		real(dp), dimension(:), intent(inout), contiguous	flowja,
		real(dp), intent(inout)	ccratin,
		real(dp), intent(inout)	ccratout
	)

Definition at line 466 of file gwt-uzt.f90.

     ! -- modules
     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(inout) :: idx
     real(DP), dimension(:), intent(in) :: x
     real(DP), dimension(:), contiguous, intent(inout) :: flowja
     real(DP), intent(inout) :: ccratin
     real(DP), intent(inout) :: ccratout
     ! -- local
     integer(I4B) :: j, n1, n2
     integer(I4B) :: nlist
     real(DP) :: q
     ! -- formats
     !
     ! -- INFILTRATION
     idx = idx + 1
     nlist = this%flowbudptr%budterm(this%idxbudinfl)%nlist
     call this%budobj%budterm(idx)%reset(nlist)
     do j = 1, nlist
       call this%uzt_infl_term(j, n1, n2, q)
       call this%budobj%budterm(idx)%update_term(n1, n2, q)
       call this%apt_accumulate_ccterm(n1, q, ccratin, ccratout)
     end do
     !
     ! -- REJ-INF
     if (this%idxbudrinf /= 0) then
       idx = idx + 1
       nlist = this%flowbudptr%budterm(this%idxbudrinf)%nlist
       call this%budobj%budterm(idx)%reset(nlist)
       do j = 1, nlist
         call this%uzt_rinf_term(j, n1, n2, q)
         call this%budobj%budterm(idx)%update_term(n1, n2, q)
         call this%apt_accumulate_ccterm(n1, q, ccratin, ccratout)
       end do
     end if
     !
     ! -- UZET
     if (this%idxbuduzet /= 0) then
       idx = idx + 1
       nlist = this%flowbudptr%budterm(this%idxbuduzet)%nlist
       call this%budobj%budterm(idx)%reset(nlist)
       do j = 1, nlist
         call this%uzt_uzet_term(j, n1, n2, q)
         call this%budobj%budterm(idx)%update_term(n1, n2, q)
         call this%apt_accumulate_ccterm(n1, q, ccratin, ccratout)
       end do
     end if
     !
     ! -- REJ-INF-TO-MVR
     if (this%idxbudritm /= 0) then
       idx = idx + 1
       nlist = this%flowbudptr%budterm(this%idxbudritm)%nlist
       call this%budobj%budterm(idx)%reset(nlist)
       do j = 1, nlist
         call this%uzt_ritm_term(j, n1, n2, q)
         call this%budobj%budterm(idx)%update_term(n1, n2, q)
         call this%apt_accumulate_ccterm(n1, q, ccratin, ccratout)
       end do
     end if

◆ uzt_get_nbudterms()

integer(i4b) function gwtuztmodule::uzt_get_nbudterms ( class(gwtuzttype) this )

This overrides function in parent.

Definition at line 364 of file gwt-uzt.f90.

     ! -- modules
     ! -- dummy
     class(GwtUztType) :: this
     ! -- return
     integer(I4B) :: nbudterms
     ! -- local
     !
     ! -- Number of budget terms is 4
     nbudterms = 0
     if (this%idxbudinfl /= 0) nbudterms = nbudterms + 1
     if (this%idxbudrinf /= 0) nbudterms = nbudterms + 1
     if (this%idxbuduzet /= 0) nbudterms = nbudterms + 1
     if (this%idxbudritm /= 0) nbudterms = nbudterms + 1

◆ uzt_infl_term()

subroutine gwtuztmodule::uzt_infl_term	(	class(gwtuzttype)	this,
		integer(i4b), intent(in)	ientry,
		integer(i4b), intent(inout)	n1,
		integer(i4b), intent(inout)	n2,
		real(dp), intent(inout), optional	rrate,
		real(dp), intent(inout), optional	rhsval,
		real(dp), intent(inout), optional	hcofval
	)

Accounts for mass added to the subsurface via infiltration. For example, mass entering the model domain via rainfall or irrigation.

Definition at line 611 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(in) :: ientry
     integer(I4B), intent(inout) :: n1
     integer(I4B), intent(inout) :: n2
     real(DP), intent(inout), optional :: rrate
     real(DP), intent(inout), optional :: rhsval
     real(DP), intent(inout), optional :: hcofval
     ! -- local
     real(DP) :: qbnd
     real(DP) :: ctmp
     real(DP) :: h, r
     !
     n1 = this%flowbudptr%budterm(this%idxbudinfl)%id1(ientry)
     n2 = this%flowbudptr%budterm(this%idxbudinfl)%id2(ientry)
     ! -- note that qbnd is negative for negative infiltration
     qbnd = this%flowbudptr%budterm(this%idxbudinfl)%flow(ientry)
     if (qbnd < dzero) then
       ctmp = this%xnewpak(n1)
       h = qbnd
       r = dzero
     else
       ctmp = this%concinfl(n1)
       h = dzero
       r = -qbnd * ctmp
     end if
     if (present(rrate)) rrate = qbnd * ctmp
     if (present(rhsval)) rhsval = r
     if (present(hcofval)) hcofval = h

◆ uzt_rinf_term()

subroutine gwtuztmodule::uzt_rinf_term	(	class(gwtuzttype)	this,
		integer(i4b), intent(in)	ientry,
		integer(i4b), intent(inout)	n1,
		integer(i4b), intent(inout)	n2,
		real(dp), intent(inout), optional	rrate,
		real(dp), intent(inout), optional	rhsval,
		real(dp), intent(inout), optional	hcofval
	)

Accounts for mass that is added to the model from specifying an infiltration rate and concentration, but is subsequently removed from the model as that portion of the infiltration that is rejected (and NOT transferred to another advanced package via the MVR/MVT packages).

Definition at line 651 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(in) :: ientry
     integer(I4B), intent(inout) :: n1
     integer(I4B), intent(inout) :: n2
     real(DP), intent(inout), optional :: rrate
     real(DP), intent(inout), optional :: rhsval
     real(DP), intent(inout), optional :: hcofval
     ! -- local
     real(DP) :: qbnd
     real(DP) :: ctmp
     !
     n1 = this%flowbudptr%budterm(this%idxbudrinf)%id1(ientry)
     n2 = this%flowbudptr%budterm(this%idxbudrinf)%id2(ientry)
     qbnd = this%flowbudptr%budterm(this%idxbudrinf)%flow(ientry)
     ctmp = this%concinfl(n1)
     if (present(rrate)) rrate = ctmp * qbnd
     if (present(rhsval)) rhsval = dzero
     if (present(hcofval)) hcofval = qbnd

◆ uzt_ritm_term()

subroutine gwtuztmodule::uzt_ritm_term	(	class(gwtuzttype)	this,
		integer(i4b), intent(in)	ientry,
		integer(i4b), intent(inout)	n1,
		integer(i4b), intent(inout)	n2,
		real(dp), intent(inout), optional	rrate,
		real(dp), intent(inout), optional	rhsval,
		real(dp), intent(inout), optional	hcofval
	)

Accounts for energy that is added to the model from specifying an infiltration rate and temperature, but does not infiltrate into the subsurface. This subroutine is called when the rejected infiltration is transferred to another advanced package via the MVR/MVT packages.

Definition at line 718 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(in) :: ientry
     integer(I4B), intent(inout) :: n1
     integer(I4B), intent(inout) :: n2
     real(DP), intent(inout), optional :: rrate
     real(DP), intent(inout), optional :: rhsval
     real(DP), intent(inout), optional :: hcofval
     ! -- local
     real(DP) :: qbnd
     real(DP) :: ctmp
     !
     n1 = this%flowbudptr%budterm(this%idxbudritm)%id1(ientry)
     n2 = this%flowbudptr%budterm(this%idxbudritm)%id2(ientry)
     qbnd = this%flowbudptr%budterm(this%idxbudritm)%flow(ientry)
     ctmp = this%concinfl(n1)
     if (present(rrate)) rrate = ctmp * qbnd
     if (present(rhsval)) rhsval = dzero
     if (present(hcofval)) hcofval = qbnd

◆ uzt_rp_obs()

subroutine gwtuztmodule::uzt_rp_obs	(	class(gwtuzttype), intent(inout)	this,
		type(observetype), intent(inout)	obsrv,
		logical, intent(inout)	found
	)

Method to process specific observations for this package.

Parameters

[in,out]	this	package class
[in,out]	obsrv	observation object
[in,out]	found	indicate whether observation was found

Definition at line 813 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType), intent(inout) :: this !< package class
     type(ObserveType), intent(inout) :: obsrv !< observation object
     logical, intent(inout) :: found !< indicate whether observation was found
     ! -- local
     !
     found = .true.
     select case (obsrv%ObsTypeId)
     case ('INFILTRATION')
       call this%rp_obs_byfeature(obsrv)
     case ('REJ-INF')
       call this%rp_obs_byfeature(obsrv)
     case ('UZET')
       call this%rp_obs_byfeature(obsrv)
     case ('REJ-INF-TO-MVR')
       call this%rp_obs_byfeature(obsrv)
     case default
       found = .false.
     end select

◆ uzt_set_stressperiod()

subroutine gwtuztmodule::uzt_set_stressperiod	(	class(gwtuzttype), intent(inout)	this,
		integer(i4b), intent(in)	itemno,
		character(len=*), intent(in)	keyword,
		logical, intent(inout)	found
	)

Definition at line 872 of file gwt-uzt.f90.

     use timeseriesmanagermodule, only: read_value_or_time_series_adv
     ! -- dummy
     class(GwtUztType), intent(inout) :: this
     integer(I4B), intent(in) :: itemno
     character(len=*), intent(in) :: keyword
     logical, intent(inout) :: found
     ! -- local
     character(len=LINELENGTH) :: temp_text
     integer(I4B) :: ierr
     integer(I4B) :: jj
     real(DP), pointer :: bndElem => null()
     ! -- formats
     !
     ! INFILTRATION <infiltration>
     ! UZET <uzet>
     !
     found = .true.
     select case (keyword)
     case ('INFILTRATION')
       ierr = this%apt_check_valid(itemno)
       if (ierr /= 0) then
         goto 999
       end if
       call this%parser%GetString(temp_text)
       jj = 1
       bndelem => this%concinfl(itemno)
       call read_value_or_time_series_adv(temp_text, itemno, jj, bndelem, &
                                          this%packName, 'BND', this%tsManager, &
                                          this%iprpak, 'INFILTRATION')
     case ('UZET')
       ierr = this%apt_check_valid(itemno)
       if (ierr /= 0) then
         goto 999
       end if
       call this%parser%GetString(temp_text)
       jj = 1
       bndelem => this%concuzet(itemno)
       call read_value_or_time_series_adv(temp_text, itemno, jj, bndelem, &
                                          this%packName, 'BND', this%tsManager, &
                                          this%iprpak, 'UZET')
     case default
       !
       ! -- keyword not recognized so return to caller with found = .false.
       found = .false.
     end select
     !
 999 continue

Here is the call graph for this function:

◆ uzt_setup_budobj()

subroutine gwtuztmodule::uzt_setup_budobj	(	class(gwtuzttype)	this,
		integer(i4b), intent(inout)	idx
	)

Definition at line 396 of file gwt-uzt.f90.

     ! -- modules
     use constantsmodule, only: lenbudtxt
     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(inout) :: idx
     ! -- local
     integer(I4B) :: maxlist, naux
     character(len=LENBUDTXT) :: text
     !
     ! -- Infiltration flux
     text = '    INFILTRATION'
     idx = idx + 1
     maxlist = this%flowbudptr%budterm(this%idxbudinfl)%maxlist
     naux = 0
     call this%budobj%budterm(idx)%initialize(text, &
                                              this%name_model, &
                                              this%packName, &
                                              this%name_model, &
                                              this%packName, &
                                              maxlist, .false., .false., &
                                              naux)
     !
     ! -- Rejected infiltration flux (and subsequently removed from the model)
     if (this%idxbudrinf /= 0) then
       text = '         REJ-INF'
       idx = idx + 1
       maxlist = this%flowbudptr%budterm(this%idxbudrinf)%maxlist
       naux = 0
       call this%budobj%budterm(idx)%initialize(text, &
                                                this%name_model, &
                                                this%packName, &
                                                this%name_model, &
                                                this%packName, &
                                                maxlist, .false., .false., &
                                                naux)
     end if
     !
     ! -- Evapotranspiration flux originating from the unsaturated zone
     if (this%idxbuduzet /= 0) then
       text = '            UZET'
       idx = idx + 1
       maxlist = this%flowbudptr%budterm(this%idxbuduzet)%maxlist
       naux = 0
       call this%budobj%budterm(idx)%initialize(text, &
                                                this%name_model, &
                                                this%packName, &
                                                this%name_model, &
                                                this%packName, &
                                                maxlist, .false., .false., &
                                                naux)
     end if
     !
     ! -- Rejected infiltration flux that is transferred to the MVR/MVT packages
     if (this%idxbudritm /= 0) then
       text = '  INF-REJ-TO-MVR'
       idx = idx + 1
       maxlist = this%flowbudptr%budterm(this%idxbudritm)%maxlist
       naux = 0
       call this%budobj%budterm(idx)%initialize(text, &
                                                this%name_model, &
                                                this%packName, &
                                                this%name_model, &
                                                this%packName, &
                                                maxlist, .false., .false., &
                                                naux)
     end if

◆ uzt_solve()

subroutine gwtuztmodule::uzt_solve ( class(gwtuzttype) this )

Add terms specific to the unsaturated zone to the explicit unsaturated- zone solve

Definition at line 319 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     ! -- local
     integer(I4B) :: j
     integer(I4B) :: n1, n2
     real(DP) :: rrate
     !
     ! -- add infiltration contribution
     if (this%idxbudinfl /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudinfl)%nlist
         call this%uzt_infl_term(j, n1, n2, rrate)
         this%dbuff(n1) = this%dbuff(n1) + rrate
       end do
     end if
     !
     ! -- add rejected infiltration contribution
     if (this%idxbudrinf /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudrinf)%nlist
         call this%uzt_rinf_term(j, n1, n2, rrate)
         this%dbuff(n1) = this%dbuff(n1) + rrate
       end do
     end if
     !
     ! -- add unsaturated et contribution
     if (this%idxbuduzet /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbuduzet)%nlist
         call this%uzt_uzet_term(j, n1, n2, rrate)
         this%dbuff(n1) = this%dbuff(n1) + rrate
       end do
     end if
     !
     ! -- add rejected infiltration to mover contribution
     if (this%idxbudritm /= 0) then
       do j = 1, this%flowbudptr%budterm(this%idxbudritm)%nlist
         call this%uzt_ritm_term(j, n1, n2, rrate)
         this%dbuff(n1) = this%dbuff(n1) + rrate
       end do
     end if

◆ uzt_uzet_term()

subroutine gwtuztmodule::uzt_uzet_term	(	class(gwtuzttype)	this,
		integer(i4b), intent(in)	ientry,
		integer(i4b), intent(inout)	n1,
		integer(i4b), intent(inout)	n2,
		real(dp), intent(inout), optional	rrate,
		real(dp), intent(inout), optional	rhsval,
		real(dp), intent(inout), optional	hcofval
	)

Accounts for mass removed as a result of evapotranspiration from the unsaturated zone.

Definition at line 679 of file gwt-uzt.f90.

     ! -- dummy
     class(GwtUztType) :: this
     integer(I4B), intent(in) :: ientry
     integer(I4B), intent(inout) :: n1
     integer(I4B), intent(inout) :: n2
     real(DP), intent(inout), optional :: rrate
     real(DP), intent(inout), optional :: rhsval
     real(DP), intent(inout), optional :: hcofval
     ! -- local
     real(DP) :: qbnd
     real(DP) :: ctmp
     real(DP) :: omega
     !
     n1 = this%flowbudptr%budterm(this%idxbuduzet)%id1(ientry)
     n2 = this%flowbudptr%budterm(this%idxbuduzet)%id2(ientry)
     ! -- note that qbnd is negative for uzet
     qbnd = this%flowbudptr%budterm(this%idxbuduzet)%flow(ientry)
     ctmp = this%concuzet(n1)
     if (this%xnewpak(n1) < ctmp) then
       omega = done
     else
       omega = dzero
     end if
     if (present(rrate)) &
       rrate = omega * qbnd * this%xnewpak(n1) + &
               (done - omega) * qbnd * ctmp
     if (present(rhsval)) rhsval = -(done - omega) * qbnd * ctmp
     if (present(hcofval)) hcofval = omega * qbnd

Variable Documentation

◆ flowtype

character(len=*), parameter gwtuztmodule::flowtype = 'UZF'

Definition at line 44 of file gwt-uzt.f90.

44 character(len=*), parameter :: flowtype = 'UZF'

◆ ftype

character(len=*), parameter gwtuztmodule::ftype = 'UZT'

Definition at line 43 of file gwt-uzt.f90.

43 character(len=*), parameter :: ftype = 'UZT'

◆ text

character(len=16) gwtuztmodule::text = ' UZT'

Definition at line 45 of file gwt-uzt.f90.

45 character(len=16) :: text = ' UZT'

Data Types

Functions/Subroutines

Variables

Function/Subroutine Documentation

◆ allocate_scalars()

◆ find_uzt_package()

◆ get_mvr_depvar()

◆ uzt_allocate_arrays()

◆ uzt_bd_obs()

◆ uzt_create()

◆ uzt_da()

◆ uzt_df_obs()

◆ uzt_fc_expanded()

◆ uzt_fill_budobj()

◆ uzt_get_nbudterms()

◆ uzt_infl_term()

◆ uzt_rinf_term()

◆ uzt_ritm_term()

◆ uzt_rp_obs()

◆ uzt_set_stressperiod()

◆ uzt_setup_budobj()

◆ uzt_solve()

◆ uzt_uzet_term()

Variable Documentation

◆ flowtype

◆ ftype

◆ text