gwtgwtconnectionmodule Module Reference

Data Types
type	gwtgwtconnectiontype
	Connects a GWT model to other GWT models in space. Derives from NumericalExchangeType so the solution can use it to fetch the coefficients for this connection. More...

Functions/Subroutines
subroutine	gwtgwtconnection_ctor (this, model, gwtEx)
	Basic construction of the connection. More...
subroutine	allocate_scalars (this)
	Allocate scalar variables for this connection. More...
subroutine	gwtgwtcon_df (this)
	define the GWT-GWT connection More...
subroutine	cfg_dist_vars (this)
	Configure distributed variables for this interface model. More...
subroutine	allocate_arrays (this)
	Allocate array variables for this connection. More...
subroutine	setgridextent (this)
	Set required extent of the interface grid from. More...
subroutine	gwtgwtcon_ar (this)
	allocate and read/set the connection's data structures More...
subroutine	validateconnection (this)
	validate this connection prior to constructing More...
subroutine	gwtgwtcon_rp (this)
subroutine	gwtgwtcon_ad (this)
	Advance this connection. More...
subroutine	gwtgwtcon_fc (this, kiter, matrix_sln, rhs_sln, inwtflag)
subroutine	gwtgwtcon_cq (this, icnvg, isuppress_output, isolnid)
subroutine	setflowtoexchange (this)
	Set the flows (flowja from interface model) to the. More...
subroutine	gwtgwtcon_bd (this, icnvg, isuppress_output, isolnid)
subroutine	gwtgwtcon_ot (this)
subroutine	gwtgwtcon_da (this)
class(gwtgwtconnectiontype) function, pointer, public	castasgwtgwtconnection (obj)
	Cast to GwtGwtConnectionType. More...

Function/Subroutine Documentation

allocate_arrays()

subroutine gwtgwtconnectionmodule::allocate_arrays ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 240 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    call mem_allocate(this%exgflowjaGwt, this%ig_builder%nrOfBoundaryCells, &
                      'EXGFLOWJAGWT', this%memoryPath)
 

allocate_scalars()

subroutine gwtgwtconnectionmodule::allocate_scalars

(

class(gwtgwtconnectiontype)

this

)

Parameters

this	the connection

Definition at line 138 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    call mem_allocate(this%iIfaceAdvScheme, 'IADVSCHEME', this%memoryPath)
    call mem_allocate(this%iIfaceXt3d, 'IXT3D', this%memoryPath)
    call mem_allocate(this%exgflowSign, 'EXGFLOWSIGN', this%memoryPath)
 

castasgwtgwtconnection()

class(gwtgwtconnectiontype) function, pointer, public gwtgwtconnectionmodule::castasgwtgwtconnection

(

class(*), intent(inout), pointer

obj

)

Parameters

[in,out]

obj

object to be cast

Returns

the GwtGwtConnection

Definition at line 491 of file GwtGwtConnection.f90.

    implicit none
    class(*), pointer, intent(inout) :: obj !< object to be cast
    class(GwtGwtConnectionType), pointer :: res !< the GwtGwtConnection
 
    res => null()
    if (.not. associated(obj)) return
 
    select type (obj)
    class is (gwtgwtconnectiontype)
      res => obj
    end select

Here is the caller graph for this function:

cfg_dist_vars()

subroutine gwtgwtconnectionmodule::cfg_dist_vars ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 206 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    call this%cfg_dv('X', '', sync_nds, &
                     (/stg_bfr_con_ar, stg_bfr_exg_ad, stg_bfr_exg_cf/))
    call this%cfg_dv('IBOUND', '', sync_nds, (/stg_bfr_con_ar/))
    call this%cfg_dv('TOP', 'DIS', sync_nds, (/stg_bfr_con_ar/))
    call this%cfg_dv('BOT', 'DIS', sync_nds, (/stg_bfr_con_ar/))
    call this%cfg_dv('AREA', 'DIS', sync_nds, (/stg_bfr_con_ar/))
    if (this%gwtInterfaceModel%dsp%idiffc > 0) then
      call this%cfg_dv('DIFFC', 'DSP', sync_nds, (/stg_bfr_con_ar/))
    end if
    if (this%gwtInterfaceModel%dsp%idisp > 0) then
      call this%cfg_dv('ALH', 'DSP', sync_nds, (/stg_bfr_con_ar/))
      call this%cfg_dv('ALV', 'DSP', sync_nds, (/stg_bfr_con_ar/))
      call this%cfg_dv('ATH1', 'DSP', sync_nds, (/stg_bfr_con_ar/))
      call this%cfg_dv('ATH2', 'DSP', sync_nds, (/stg_bfr_con_ar/))
      call this%cfg_dv('ATV', 'DSP', sync_nds, (/stg_bfr_con_ar/))
    end if
    call this%cfg_dv('GWFHEAD', 'FMI', sync_nds, (/stg_bfr_exg_ad/))
    call this%cfg_dv('GWFSAT', 'FMI', sync_nds, (/stg_bfr_exg_ad/))
    call this%cfg_dv('GWFSPDIS', 'FMI', sync_nds, (/stg_bfr_exg_ad/))
    call this%cfg_dv('GWFFLOWJA', 'FMI', sync_con, (/stg_bfr_exg_ad/))
    call this%cfg_dv('GWFFLOWJA', 'FMI', sync_exg, (/stg_bfr_exg_ad/), &
                     exg_var_name='GWFSIMVALS')
    ! fill thetam from mst packages, needed for dsp
    if (this%gwtModel%indsp > 0 .and. this%gwtModel%inmst > 0) then
      call this%cfg_dv('THETAM', 'MST', sync_nds, (/stg_aft_con_ar/))
    end if
 

gwtgwtcon_ad()

subroutine gwtgwtconnectionmodule::gwtgwtcon_ad ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	this connection

Definition at line 362 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< this connection
 
    ! recalculate dispersion ellipse
    if (this%gwtInterfaceModel%indsp > 0) call this%gwtInterfaceModel%dsp%dsp_ad()
 
    if (this%owns_exchange) then
      call this%gwtExchange%exg_ad()
    end if
 

gwtgwtcon_ar()

subroutine gwtgwtconnectionmodule::gwtgwtcon_ar ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 280 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    ! check if we can construct an interface model
    ! NB: only makes sense after the models' allocate&read have been
    ! called, which is why we do it here
    call this%validateConnection()
 
    ! allocate and read base
    call this%spatialcon_ar()
 
    ! ... and now the interface model
    call this%gwtInterfaceModel%model_ar()
 
    ! AR the movers and obs through the exchange
    if (this%owns_exchange) then
      !cdl implement this when MVT is ready
      !cdl if (this%gwtExchange%inmvt > 0) then
      !cdl   call this%gwtExchange%mvt%mvt_ar()
      !cdl end if
      if (this%gwtExchange%inobs > 0) then
        call this%gwtExchange%obs%obs_ar()
      end if
    end if
 

gwtgwtcon_bd()

subroutine gwtgwtconnectionmodule::gwtgwtcon_bd	(	class(gwtgwtconnectiontype)	this,
		integer(i4b), intent(inout)	icnvg,
		integer(i4b), intent(in)	isuppress_output,
		integer(i4b), intent(in)	isolnid
	)

Parameters

	this	the connection
[in,out]	icnvg	convergence flag
[in]	isuppress_output	suppress output when =1
[in]	isolnid	solution id

Definition at line 430 of file GwtGwtConnection.f90.

    use budgetmodule, only: rate_accumulator
    class(GwtGwtConnectionType) :: this !< the connection
    integer(I4B), intent(inout) :: icnvg !< convergence flag
    integer(I4B), intent(in) :: isuppress_output !< suppress output when =1
    integer(I4B), intent(in) :: isolnid !< solution id
 
    ! call exchange budget routine, also calls bd
    ! for movers.
    if (this%owns_exchange) then
      call this%gwtExchange%exg_bd(icnvg, isuppress_output, isolnid)
    end if
 

Here is the call graph for this function:

gwtgwtcon_cq()

subroutine gwtgwtconnectionmodule::gwtgwtcon_cq ( class(gwtgwtconnectiontype)  this, integer(i4b), intent(inout)  icnvg, integer(i4b), intent(in)  isuppress_output, integer(i4b), intent(in)  isolnid  )

private

Parameters

	this	the connection
[in,out]	icnvg	convergence flag
[in]	isuppress_output	suppress output when =1
[in]	isolnid	solution id

Definition at line 395 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
    integer(I4B), intent(inout) :: icnvg !< convergence flag
    integer(I4B), intent(in) :: isuppress_output !< suppress output when =1
    integer(I4B), intent(in) :: isolnid !< solution id
 
    call this%gwtInterfaceModel%model_cq(icnvg, isuppress_output)
    call this%setFlowToExchange()
 

gwtgwtcon_da()

subroutine gwtgwtconnectionmodule::gwtgwtcon_da ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 457 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
    ! local
    logical(LGP) :: isOpen
 
    ! scalars
    call mem_deallocate(this%iIfaceAdvScheme)
    call mem_deallocate(this%iIfaceXt3d)
    call mem_deallocate(this%exgflowSign)
 
    ! arrays
    call mem_deallocate(this%exgflowjaGwt)
 
    ! interface model
    call this%gwtInterfaceModel%model_da()
    deallocate (this%gwtInterfaceModel)
 
    ! dealloc base
    call this%spatialcon_da()
 
    inquire (this%iout, opened=isopen)
    if (isopen) then
      close (this%iout)
    end if
 
    ! we need to deallocate the exchange we own:
    if (this%owns_exchange) then
      call this%gwtExchange%exg_da()
    end if
 

gwtgwtcon_df()

subroutine gwtgwtconnectionmodule::gwtgwtcon_df ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 149 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
    ! local
    character(len=LENCOMPONENTNAME) :: imName
 
    ! determine advection scheme (the GWT-GWT exchange
    ! has been read at this point)
    this%iIfaceAdvScheme = this%gwtExchange%iAdvScheme
    !
    ! determine xt3d setting on interface
    this%iIfaceXt3d = this%gwtExchange%ixt3d
 
    ! turn off when off in the owning model
    if (this%gwtModel%indsp > 0) then
      this%iIfaceXt3d = this%gwtModel%dsp%ixt3d
    end if
 
    ! determine the required size of the interface model grid
    call this%setGridExtent()
 
    ! now set up the GridConnection
    call this%spatialcon_df()
 
    ! we have to 'catch up' and create the interface model
    ! here, then the remainder of this routine will be define
    if (this%prim_exchange%v_model1 == this%owner) then
      write (imname, '(a,i0)') 'GWTIM1_', this%gwtExchange%id
    else
      write (imname, '(a,i0)') 'GWTIM2_', this%gwtExchange%id
    end if
    call this%gwtInterfaceModel%gwtifmod_cr(imname, &
                                            this%iout, &
                                            this%ig_builder)
    call this%gwtInterfaceModel%set_idsoln(this%gwtModel%idsoln)
    this%gwtInterfaceModel%iAdvScheme = this%iIfaceAdvScheme
    this%gwtInterfaceModel%ixt3d = this%iIfaceXt3d
    call this%gwtInterfaceModel%model_df()
 
    call this%cfg_dist_vars()
 
    call this%allocate_arrays()
    call this%gwtInterfaceModel%allocate_fmi()
 
    ! connect X, RHS, IBOUND, and flowja
    call this%spatialcon_setmodelptrs()
 
    ! connect pointers (used by BUY)
    this%conc => this%gwtInterfaceModel%x
    this%icbound => this%gwtInterfaceModel%ibound
 
    ! add connections from the interface model to solution matrix
    call this%spatialcon_connect()
 

gwtgwtcon_fc()

subroutine gwtgwtconnectionmodule::gwtgwtcon_fc ( class(gwtgwtconnectiontype)  this, integer(i4b), intent(in)  kiter, class(matrixbasetype), pointer  matrix_sln, real(dp), dimension(:), intent(inout)  rhs_sln, integer(i4b), intent(in), optional  inwtflag  )

private

Parameters

	this	the connection
[in]	kiter	the iteration counter
	matrix_sln	the system matrix
[in,out]	rhs_sln	global right-hand-side
[in]	inwtflag	newton-raphson flag

Definition at line 374 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
    integer(I4B), intent(in) :: kiter !< the iteration counter
    class(MatrixBaseType), pointer :: matrix_sln !< the system matrix
    real(DP), dimension(:), intent(inout) :: rhs_sln !< global right-hand-side
    integer(I4B), optional, intent(in) :: inwtflag !< newton-raphson flag
    !
 
    call this%SpatialModelConnectionType%spatialcon_fc( &
      kiter, matrix_sln, rhs_sln, inwtflag)
    !
    ! FC the movers through the exchange
    if (this%owns_exchange) then
      if (this%gwtExchange%inmvt > 0) then
        call this%gwtExchange%mvt%mvt_fc(this%gwtExchange%gwtmodel1%x, &
                                         this%gwtExchange%gwtmodel2%x)
      end if
    end if
 

gwtgwtcon_ot()

subroutine gwtgwtconnectionmodule::gwtgwtcon_ot

(

class(gwtgwtconnectiontype)

this

)

Parameters

this	the connection

Definition at line 445 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    ! Call exg_ot() here as it handles all output processing
    ! based on gwtExchange%simvals(:), which was correctly
    ! filled from gwtgwtcon
    if (this%owns_exchange) then
      call this%gwtExchange%exg_ot()
    end if
 

gwtgwtcon_rp()

subroutine gwtgwtconnectionmodule::gwtgwtcon_rp

(

class(gwtgwtconnectiontype)

this

)

Parameters

this	the connection

Definition at line 350 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
 
    ! Call exchange rp routines
    if (this%owns_exchange) then
      call this%gwtExchange%exg_rp()
    end if
 

gwtgwtconnection_ctor()

subroutine gwtgwtconnectionmodule::gwtgwtconnection_ctor	(	class(gwtgwtconnectiontype)	this,
		class(numericalmodeltype), pointer	model,
		class(disconnexchangetype), pointer	gwtEx
	)

Parameters

this	the connection
model	the model owning this connection, this must be a GwtModelType
gwtex	the GWT-GWT exchange the interface model is created for

Definition at line 82 of file GwtGwtConnection.f90.

    use inputoutputmodule, only: openfile
    class(GwtGwtConnectionType) :: this !< the connection
    class(NumericalModelType), pointer :: model !< the model owning this connection,
                                                !! this must be a GwtModelType
    class(DisConnExchangeType), pointer :: gwtEx !< the GWT-GWT exchange the interface model is created for
    ! local
    character(len=LINELENGTH) :: fname
    character(len=LENCOMPONENTNAME) :: name
    class(*), pointer :: objPtr
    logical(LGP) :: write_ifmodel_listfile = .false.
 
    objptr => model
    this%gwtModel => castasgwtmodel(objptr)
    objptr => gwtex
    this%gwtExchange => castasgwtexchange(objptr)
 
    if (gwtex%v_model1%is_local .and. gwtex%v_model2%is_local) then
      this%owns_exchange = associated(model, gwtex%model1)
    else
      this%owns_exchange = .true.
    end if
 
    if (gwtex%v_model1 == model) then
      write (name, '(a,i0)') 'GWTCON1_', gwtex%id
    else
      write (name, '(a,i0)') 'GWTCON2_', gwtex%id
    end if
 
    ! .lst file for interface model
    if (write_ifmodel_listfile) then
      fname = trim(name)//'.im.lst'
      call openfile(this%iout, 0, fname, 'LIST', filstat_opt='REPLACE')
      write (this%iout, '(4a)') 'Creating GWT-GWT connection for model ', &
        trim(this%gwtModel%name), 'from exchange ', &
        trim(gwtex%name)
    end if
 
    ! first call base constructor
    call this%SpatialModelConnectionType%spatialConnection_ctor(model, &
                                                                gwtex, &
                                                                name)
 
    call this%allocate_scalars()
    this%typename = 'GWT-GWT'
    this%iIfaceAdvScheme = 0
    this%iIfaceXt3d = 0
    this%exgflowSign = 1
 
    allocate (this%gwtInterfaceModel)
    this%interface_model => this%gwtInterfaceModel
 

Here is the call graph for this function:

Here is the caller graph for this function:

setflowtoexchange()

subroutine gwtgwtconnectionmodule::setflowtoexchange ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	this connection

Definition at line 408 of file GwtGwtConnection.f90.

    use indexmapmodule
    class(GwtGwtConnectionType) :: this !< this connection
    ! local
    integer(I4B) :: i
    class(GwtExchangeType), pointer :: gwtEx
    type(IndexMapSgnType), pointer :: map
 
    if (this%owns_exchange) then
      gwtex => this%gwtExchange
      map => this%interface_map%exchange_maps(this%interface_map%prim_exg_idx)
 
      ! use (half of) the exchange map in reverse:
      do i = 1, size(map%src_idx)
        if (map%sign(i) < 0) cycle ! simvals is defined from exg%m1 => exg%m2
        gwtex%simvals(map%src_idx(i)) = &
          this%gwtInterfaceModel%flowja(map%tgt_idx(i))
      end do
    end if
 

setgridextent()

subroutine gwtgwtconnectionmodule::setgridextent ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	the connection

Definition at line 250 of file GwtGwtConnection.f90.

    class(GwtGwtConnectionType) :: this !< the connection
    ! local
    logical(LGP) :: hasAdv, hasDsp
 
    hasadv = this%gwtModel%inadv > 0
    hasdsp = this%gwtModel%indsp > 0
 
    if (hasadv) then
      if (this%iIfaceAdvScheme == 2) then
        this%exg_stencil_depth = 2
        if (this%gwtModel%adv%iadvwt == 2) then
          this%int_stencil_depth = 2
        end if
      end if
    end if
 
    if (hasdsp) then
      if (this%iIfaceXt3d > 0) then
        this%exg_stencil_depth = 2
        if (this%gwtModel%dsp%ixt3d > 0) then
          this%int_stencil_depth = 2
        end if
      end if
    end if
 

validateconnection()

subroutine gwtgwtconnectionmodule::validateconnection ( class(gwtgwtconnectiontype)  this )

private

Parameters

this	this connection

Definition at line 309 of file GwtGwtConnection.f90.

    use simvariablesmodule, only: errmsg
    use simmodule, only: count_errors, store_error
    class(GwtGwtConnectionType) :: this !< this connection
 
    ! base validation, the spatial/geometry part
    call this%SpatialModelConnectionType%validateConnection()
 
    ! we cannot validate this (yet) in parallel mode
    if (.not. this%gwtExchange%v_model1%is_local) return
    if (.not. this%gwtExchange%v_model2%is_local) return
 
    ! GWT related matters
    if ((this%gwtExchange%gwtmodel1%inadv > 0 .and. &
         this%gwtExchange%gwtmodel2%inadv == 0) .or. &
        (this%gwtExchange%gwtmodel2%inadv > 0 .and. &
         this%gwtExchange%gwtmodel1%inadv == 0)) then
      write (errmsg, '(a,a,a)') 'Cannot connect GWT models in exchange ', &
        trim(this%gwtExchange%name), ' because one model is configured with ADV &
        &and the other one is not'
      call store_error(errmsg)
    end if
 
    if ((this%gwtExchange%gwtmodel1%indsp > 0 .and. &
         this%gwtExchange%gwtmodel2%indsp == 0) .or. &
        (this%gwtExchange%gwtmodel2%indsp > 0 .and. &
         this%gwtExchange%gwtmodel1%indsp == 0)) then
      write (errmsg, '(a,a,a)') 'Cannot connect GWT models in exchange ', &
        trim(this%gwtExchange%name), ' because one model is configured with DSP &
        &and the other one is not'
      call store_error(errmsg)
    end if
 
    ! abort on errors
    if (count_errors() > 0) then
      write (errmsg, '(a)') 'Errors occurred while processing exchange(s)'
      call ustop()
    end if
 

Here is the call graph for this function: